Tech Note 29: Pocket PC Phone Edition

Oct 29, 2002

© NSB Corporation. All rights reserved.

Go to English page.

NS Basic/CE 4.0からPocket PC Phone Editionが使い易くなり、携帯電話（cellular phone）から電話を掛けたり、コール記録を見ることができます。

あなたのプログラムでNSBasic Phoneコントロールを使うには、次のコマンドを使います。

addObject "NSBasic.Phone.1", "phone", 0, 0, 0, 0

Phoneコントロールはデバイスにインストールされレジスターされていなければなりません。詳細はTech Note 01を参照して下さい。

メソッド

メソッド パラメーター 内容

MakeCall

PhoneNumber (文字列型) - 電話番号
CalledParty (文字列型) - 相手
PromptBefore (ブール型) - プロンプト

指定する電話番号と相手に電話を掛ける。掛ける前にユーザに確認するプロンプトのオプションがある。

CallLogCount

無し

コール記録に収められている、合計数を返す

CallLogEntry

EntryNumber (整数型、1からCallLogCount)

特定のコール記録にポインターを向け、読込み状態にする。以下のプロパティーを使って、必要な情報を得る。

プロパティ

NSBPhoneコントロールの全てのプロパティは読込み専用で、コール記録へアクセスするために使われます。プロパティを使って情報を得る前に、必ずCallLogEntryを呼ばなければなりません。プロパティの情報を得るためのシンタックス：

value = object.property

プロパティ 内容

CLECallerIDType
 

Caller ID 情報：

0 = 入手不可
1 = ブロックされている
2 = 入手可

CLEConnected

掛けたコールは接続したか？

True = 接続した
False = 通話中／応答無し

CLEEnd

コール終了時間

CLEEnded

どのようにコールは終了したか？

True = 自発的に
False = 強制終了

CLEIOM

Incoming/Outgoing/Missed

"i" = Incoming
"o" = Outgoing
"m" = Missed

CLEName

コールに付いている名前

CLENameType

コールに付いているタイプ

"w" = Work
"h" = Home

CLENote

コールに付いているNotesファイル名（Notesファイルがある場合のみ）

CLENumber

コールに付いている電話番号

CLEOutgoing

このコールは掛けたものか？

True/False

CLERoam

このコールはローミングして掛けられたか？

True/False
CLEStart コール開始時間

サンプル

'NSBPhone example
'
'Add the NSBasic Phone control
AddObject "NSBPhone.NSBPhone.1", "phone", 0,0,0,0

'Add a labeled text box for phone number entry
AddObject "Label", "lblNumber", 5,5,110,16
lblNumber.Caption = "Phone Number:"
lblNumber.BackColor = Output.BackColor
AddObject "TextBox", "txtNumber", 5,25,160,20

'Add a labeled text box for callee name entry
AddObject "Label", "lblName", 5,50,110,16
lblName.Caption = "Name:"
lblName.BackColor = Output.BackColor
AddObject "TextBox", "txtName", 5,70,160,20

'Add a button to initiate the call
AddObject "CommandButton", "btnDial", 170,25,65,65
btnDial.Text = "Dial"

'Use a grid object to represent some info from the call log
AddObject "Grid", "grdLog", 5,95,230,170
grdLog.Redraw = False
grdLog.Rows = phone.CallLogCount
grdLog.Cols = 5
grdLog.ColWidth(0) = 180
grdLog.ColWidth(1) = 1650
grdLog.ColWidth(2) = 1650
grdLog.ColWidth(3) = 1200
grdLog.ColWidth(4) = 1500
For i = 1 To phone.CallLogCount
   phone.CallLogEntry i
   grdLog.TextMatrix(i-1, 0) = phone.CLEIOM
   grdLog.TextMatrix(i-1, 1) = phone.CLEStart
   grdLog.TextMatrix(i-1, 2) = phone.CLEEnd
   grdLog.TextMatrix(i-1, 3) = phone.CLENumber
   grdLog.TextMatrix(i-1, 4) = phone.CLEName
Next
grdLog.Redraw = True

'When the button is tapped, make the call, but don't prompt before dialing
Sub btnDial_Click
   phone.MakeCall txtNumber.Text, txtName.Text, False
End Sub